Private Sub cmd_Play_Click(ByVal sender As System.Object, _
      ByVal e As System.EventArgs) Handles cmd_Play.Click
  Dim myDSoundBufferDesc As New BufferDescription
  Dim myBufferCaps As BufferCaps
  Dim intGesamtBytes As Integer
  Dim intLastAdress As Integer
  Dim i As Integer
  'den eingegebenen Ziffern entsprechend werden die Sounds
  'eingelesen und in einen neuen SoundBuffer geschrieben.
  'Natürlich könnte man auch direkt die entsprechenden Sounds
  'abspielen, aber dies hätte zur Folge das alle Sounds zur
  'gleichen Zeit abgespielt werden.
  '-> die Sounds sollen nach einander abgespielt werden.
  If Trim(txt_Zahl.Text).Length > 0 Then
    If Not IsNumeric(txt_Zahl.Text) Then Exit Sub
    'feststellen der Länge alles Sounds in Byte
    For i = 1 To txt_Zahl.Text.Length
      myBufferCaps = _
            DSSounds(CInt(Mid(txt_Zahl.Text, i, 1))).Caps()
      intGesamtBytes += myBufferCaps.BufferBytes
    Next
    'auslesen des WaveFormat von einem der Sounds
    'und in den neuen SoundBuffer setzen
    myDSoundBufferDesc.Format = DSSounds(0).Format
    myDSoundBufferDesc.StaticBuffer = True
    'festlegen der Grösse des SoundBuffer's
    myDSoundBufferDesc.BufferBytes = intGesamtBytes
    'erstellen des neuen SoundBuffer's
    If Not DSAll Is Nothing Then DSAll = Nothing
    DSAll = New SecondaryBuffer(myDSoundBufferDesc, DSoundDevice)
    'In dieser Schleife werden die Daten aller Sounds
    'ausgelesen und nacheinander in den neuen SecondaryBuffer
    'geschrieben. Es würde auch mit einem MemoryStream gehen,
    'aber da der neue Sound auch gespeichert werden soll,
    'ist es besser die Daten als Byte-Array zu haben.
    Dim BufferData As Byte() = Nothing
    'Der neue Sound soll gespeichert werden, daher wird eine 
    'WAV Datei mit einem entsprechendem Header erzeugt.
    If chk_Save.Checked Then
      CreateRIFF(Application.StartupPath & "\DTMFTon.wav", _
        DSSounds(0).Format, intGesamtBytes)
    End If
    For i = 1 To txt_Zahl.Text.Length
      myBufferCaps = _
            DSSounds(CInt(Mid(txt_Zahl.Text, i, 1))).Caps()
      'Auslesen der Bytes
      BufferData = _
        CType(DSSounds(CInt(Mid(txt_Zahl.Text, i, 1))).Read(0, _
        GetType(Byte), LockFlag.None, myBufferCaps.BufferBytes), _
        Byte())
      'Schreiben des Byte-Arrays in den neuen Buffer
      DSAll.Write(intLastAdress, BufferData, LockFlag.None)
      intLastAdress += myBufferCaps.BufferBytes
      'und wenn gewünscht auch in das WAV File
      If chk_Save.Checked Then
        Writer.Write(BufferData, 0, BufferData.Length)
      End If
    Next
    'Falls der neue Sound gespeichert werden soll,
    'muss der Writer noch geschlossen werden
    If chk_Save.Checked Then
      Writer.Close()
      Writer = Nothing
      WaveFile = Nothing
    End If
    DSAll.SetCurrentPosition(0)
    DSAll.Play(0, BufferPlayFlags.Default)
  End If
End Sub