Option Explicit

Dim SindWirDerServer As Boolean

Private Const HDR_CONNECT As Integer = 1111
Private Const HDR_CLOSE As Integer = 1112
Private Const HDR_MESSAGE As Integer = 1113

Private Sub cmd_StartClient_Click()
  wskClient.LocalPort = CLng(txt_Port.Text)
  wskClient.RemoteHost = txt_IP.Text
  wskClient.RemotePort = CLng(txt_Port.Text)
  wskClient.SendData HDR_CONNECT & "Client"
  cmd_StartClient.Enabled = False
  cmd_StartServer.Enabled = False
End Sub

Private Sub cmd_StartServer_Click()
  wskServer.Bind CLng(txt_Port.Text)
  SindWirDerServer = True
  cmd_StartClient.Enabled = False
  cmd_StartServer.Enabled = False
End Sub

Private Sub cmd_Senden_Click()
  If SindWirDerServer Then
    If wskServer.State = sckOpen Then
      skServer.SendData HDR_MESSAGE & txt_Senden.Text
    End If
  Else
    If wskClient.State = sckOpen Then
      wskClient.SendData HDR_MESSAGE & txt_Senden.Text
    End If
  End If
End Sub

Private Sub wskClient_DataArrival(ByVal bytesTotal As Long)
  Dim hlpString As String

  wskClient.GetData hlpString, vbString
  Select Case CInt(Mid(hlpString, 1, 4))
    Case HDR_CONNECT
      lbl_IncomingText(1).Caption = "Verbindung hergestellt"
    Case HDR_CLOSE
      MsgBox "Server hat Verbindung abgebrochen."
      wskClient.Close
      cmd_StartClient.Enabled = True
      cmd_StartServer.Enabled = True
    Case HDR_MESSAGE
      lbl_IncomingText(1).Caption = Mid(hlpString, 5)
  End Select
End Sub

Private Sub wskServer_DataArrival(ByVal bytesTotal As Long)
  Dim hlpString As String

  wskServer.GetData hlpString, vbString
  Select Case CInt(Mid(hlpString, 1, 4))
    Case HDR_CONNECT
      lbl_IncomingText(1).Caption = "Verbindung hergestellt"
      wskServer.SendData HDR_CONNECT & "Server"
    Case HDR_CLOSE
      MsgBox "Client hat Verbindung abgebrochen."
      wskServer.Close
      SindWirDerServer = False
      cmd_StartClient.Enabled = True
      cmd_StartServer.Enabled = True
    Case HDR_MESSAGE
      lbl_IncomingText(1).Caption = Mid(hlpString, 5)
  End Select
End Sub

Private Sub Timer1_Timer()
  Dim lngAktuellerStatus As Long

  If SindWirDerServer Then
    lngAktuellerStatus = wskServer.State
  Else
    lngAktuellerStatus = wskClient.State
  End If

  Select Case lngAktuellerStatus
    Case sckClosed
      lbl_WinsockStatus(1).Caption = "Socket closed"
    Case sckOpen
      lbl_WinsockStatus(1).Caption = "Socket open"
    Case sckListening
      lbl_WinsockStatus(1).Caption = "Listening..."
    Case sckConnectionPending
      lbl_WinsockStatus(1).Caption = "Connection pending"
    Case sckResolvingHost
      lbl_WinsockStatus(1).Caption = "Resolving host..."
    Case sckHostResolved
      lbl_WinsockStatus(1).Caption = "Host resolved"
    Case sckConnecting
      lbl_WinsockStatus(1).Caption = "Connecting..."
    Case sckConnected
      lbl_WinsockStatus(1).Caption = "Connected"
    Case sckClosing
      lbl_WinsockStatus(1).Caption = "Closing..."
    Case sckError
      lbl_WinsockStatus(1).Caption = "Error"
  End Select
End Sub

Private Sub cmd_Beenden_Click()
  cmd_Disconnect_Click
  Unload Me
  End
End Sub

Private Sub cmd_Disconnect_Click()
  On Error GoTo ErrOut
  If SindWirDerServer Then
    If wskServer.State = sckOpen Then
      wskServer.SendData HDR_CLOSE & "Server"
    End If
    wskServer.Close
  Else
    If wskClient.State = sckOpen Then
      wskClient.SendData HDR_CLOSE & "Client"
    End If
    wskClient.Close
  End If
  cmd_StartClient.Enabled = True
  cmd_StartServer.Enabled = True
  Exit Sub

ErrOut:
  wskServer.Close
  wskClient.Close
  cmd_StartClient.Enabled = True
  cmd_StartServer.Enabled = True
End Sub