Option Explicit

Private WithEvents mevt_Workbook As Excel.Workbook
Private m_objXLApp As Excel.Application

Private Sub cmdGridToXL_Click()
  Dim objXLWks  As Excel.Worksheet

  Dim varData() As Variant

  Dim nRows As Long
  Dim nCols As Long

  Dim r As Long
  Dim c As Long

  Me.cmdGridToXL.Enabled = False

  With MSHFlexGrid1
    nRows = .Rows - 1
    nCols = .Cols - 1

    ReDim varData(nRows, nCols)

    For r = 0 To nRows
      For c = 0 To nCols
        varData(r, c) = .TextMatrix(r, c)
      Next c
    Next r
  End With

  Set m_objXLApp = CreateObject("Excel.Application")
  Set mevt_Workbook = m_objXLApp.Workbooks.Add(-4167)

  Set objXLWks = mevt_Workbook.Worksheets(1)
  objXLWks.Name = "MSHFlexGrid-Daten"

  nRows = nRows + 1
  nCols = nCols + 1

  objXLWks.Range("A1").Resize(nRows, nCols).Value = varData
  Erase varData

  With objXLWks.Range( _
        objXLWks.Cells(1, 2), objXLWks.Cells(1, nCols))
    .Font.Bold = True
    .Interior.ColorIndex = 36
    .HorizontalAlignment = xlCenter
    .VerticalAlignment = xlCenter
    .EntireRow.RowHeight = 20
  End With

  With objXLWks.Range( _
        objXLWks.Cells(2, 1), objXLWks.Cells(nRows, 1))
    .Font.Bold = True
    .Interior.ColorIndex = 35
  End With

  With objXLWks.Range(objXLWks.Cells(1, 1), _
        objXLWks.Cells(nRows, nCols)).Borders
    .LineStyle = xlContinuous
    .Weight = xlThin
    .ColorIndex = xlAutomatic
  End With
  Set objXLWks = Nothing

  m_objXLApp.Visible = True
End Sub

Private Sub mevt_Workbook_BeforeClose(Cancel As Boolean)
  Cancel = True
  MsgBox "Sorry... die Arbeitsmappe " & mevt_Workbook.Name & _
       vbLf & "' kann nur über den Button <Beenden> im " & _
       vbLf & "VB-Programm geschlossen werden.", _
       vbOKOnly + vbInformation + vbSystemModal, _
       Title:=Me.Caption
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, _
      UnloadMode As Integer)

  On Error Resume Next
  m_objXLApp.EnableEvents = False
  mevt_Workbook.Close Savechanges:=False
  m_objXLApp.EnableEvents = True
  Set mevt_Workbook = Nothing

  m_objXLApp.Quit
  Set m_objXLApp = Nothing
End Sub