Option Explicit

Private Declare Function InternetGetConnectedState _
    Lib "wininet.dll" (ByRef lpdwFlags As Long, _
    ByVal dwReserved As Long) As Long

Private Const INTERNET_CONNECTION_MODEM As Long = &H1
Private Const INTERNET_CONNECTION_LAN As Long = &H2
Private Const INTERNET_CONNECTION_PROXY As Long = &H4
Private Const INTERNET_CONNECTION_MODEM_BUSY As Long = &H8
Private Const INTERNET_CONNECTION_OFFLINE As Long = &H20
Private Const INTERNET_CONNECTION_CONFIGURED As Long = &H40
Private Const INTERNET_RAS_INSTALLED As Long = &H10

Private Sub Form_Load()
  Timer1.Interval = 100
End Sub

Private Sub Timer1_Timer()
  Dim dwflags As Long
  Dim sText As String
  Dim msg As String

  If InternetGetConnectedState(dwflags, 0&) Then

    If dwflags And INTERNET_CONNECTION_CONFIGURED Then
      msg = msg & _
          "Es ist eine Internetverbindung eingerichtet." & vbCrLf
    End If

    If dwflags And INTERNET_CONNECTION_LAN Then
      msg = msg & _
          "Die Internetverbindung erfolgt über ein Netzwerk"
    End If

    If dwflags And INTERNET_CONNECTION_MODEM Then
      msg = msg & "Die Internetverbindung erfolgt über ein Modem"
    End If

    If dwflags And INTERNET_CONNECTION_PROXY Then
      msg = msg & " mittels eines Proxy-Servers." & vbCrLf
    Else
      msg = msg & "." & vbCrLf
    End If

    If dwflags And INTERNET_CONNECTION_OFFLINE Then
      msg = msg & "Es besteht z.Zt. keine Internetverbindung. "
    End If

    If dwflags And INTERNET_CONNECTION_MODEM_BUSY Then
      msg = msg & "Das Modem nutzt z.Zt eine andere Verbindung. "
    End If

    If dwflags And INTERNET_RAS_INSTALLED Then
      msg = msg & _
          "Ein Remote Access Service (RAS) ist installiert. "
    End If

  Else
    msg = "Es besteht z.Zt. keine Internetverbindung."

  End If

  Label1.Caption = msg
End Sub