Option Explicit

Dim DX7 As New DirectX7
Dim MIDLoader As DirectMusicLoader
Dim MIDSeg As DirectMusicSegment
Dim MIDPerf As DirectMusicPerformance
Dim MIDSegState As DirectMusicSegmentState

Dim mtTime As Long
Dim GetStartTime As Long
Dim Offset As Long
Dim MIDInPause As Boolean

Private Sub cmd_Open_Click()
  Set MIDLoader = Nothing
  Set MIDLoader = DX7.DirectMusicLoaderCreate

  Set MIDPerf = Nothing
  Set MIDPerf = DX7.DirectMusicPerformanceCreate
  MIDPerf.Init Nothing, 0
  MIDPerf.SetPort -1, 80
  MIDPerf.SetMasterAutoDownload True

  CDialog_Open.Filter = "MIDI Files (*.mid)|*.mid"
  CDialog_Open.FileName = vbNullString
  CDialog_Open.InitDir = App.Path
  CDialog_Open.ShowOpen

  If CDialog_Open.FileName <> vbNullString Then
    Set MIDSeg = MIDLoader.LoadSegment(CDialog_Open.FileName)
    MIDSeg.SetStartPoint 0
    cmd_Play.Enabled = True
  Else
    Exit Sub
  End If
End Sub

Private Sub cmd_Play_Click()
  MIDSeg.SetStartPoint 0
  Set MIDSegState = MIDPerf.PlaySegment(MIDSeg, 0, 0)

  cmd_Play.Enabled = False
  cmd_Pause.Enabled = True
  cmd_Stop.Enabled = True
  cmd_Open.Enabled = False
  Timer1.Enabled = True
  MIDInPause = False
End Sub

Private Sub cmd_Pause_Click()
  If MIDPerf.IsPlaying(MIDSeg, MIDSegState) = True Then
    MIDInPause = True
    Timer1.Enabled = False
    mtTime = MIDPerf.GetMusicTime()
    GetStartTime = MIDSegState.GetStartTime()
    MIDPerf.Stop MIDSeg, Nothing, 0, 0

  Else
    Offset = mtTime - GetStartTime + Offset + 1
    MIDSeg.SetStartPoint Offset
    Set MIDSegState = MIDPerf.PlaySegment(MIDSeg, 0, 0)
    MIDInPause = False
    Timer1.Enabled = True
  End If
End Sub

Private Sub cmd_Stop_Click()
  MIDPerf.Stop MIDSeg, MIDSegState, 0, 0

  cmd_Play.Enabled = True
  cmd_Pause.Enabled = False
  cmd_Stop.Enabled = False
  cmd_Open.Enabled = True
  Timer1.Enabled = False
  MIDInPause = False
End Sub

Private Sub cmd_Close_Click()
  If MIDSeg Is Nothing Then
    End
  Else
    If MIDPerf.IsPlaying(MIDSeg, MIDSegState) Then
      MIDPerf.Stop MIDSeg, MIDSegState, 0, 0
    End If

    Set MIDSegState = Nothing
    Set MIDPerf = Nothing
    Set MIDSeg = Nothing
    Set MIDLoader = Nothing
    End
  End If
End Sub

Private Sub Timer1_Timer()
  If MIDInPause Then Exit Sub

  If MIDPerf.IsPlaying(MIDSeg, MIDSegState) = False Then
    Timer1.Enabled = False
    cmd_Play.Enabled = True
    cmd_Pause.Enabled = False
    cmd_Stop.Enabled = False
    cmd_Open.Enabled = True
  End If
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, _
        UnloadMode As Integer)
  cmd_Close_Click
End Sub